Vla-put-nclose

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-nclose vla-object bool )

機能: ポリメッシュを N 方向に閉じるかどうかを指定する。

引数

vla-object … PolygonMesh のVLAオブジェクト
bool … ブール型

:vlax-True: PolygonMesh が N 方向に閉じられる。
:vlax-False: PolygonMesh が N 方向に開かれる。

戻り値: nil

MEMO: PolygonMesh が閉じていると、最後の列から最初の列まで連続したものとして扱われる。PolygonMesh が開いていると、最後の列と最初の列の間で不連続なものとして扱われる。

サンプル

(vl-load-com)
(defun c:Example_NClose()
    ;; 4 x 4 のポリゴンメッシュを作成して N方向を閉じるサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; ポリゴンメッシュの定義
    (setq points (vlax-make-safearray vlax-vbDouble '(0 . 47)))
    (vlax-safearray-fill points 
                         '(2    2  1
                           2.5  2  0
                           5    2  0
                           5.5  2  1
                           2    4  0.5
                           2.5  4  0
                           5    4  0
                           5.5  4  0.5
                           2    6  0.5
                           2.5  6  0
                           5    6  0
                           5.5  6  0.5
                           2    8  1
                           2.5  8  0
                           5    8  0
                           5.5  8  1
                          )
    )
    
    (setq mSize 4
          nSize 4)
    
    ;; ポリゴンメッシュを作成
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq meshObj (vla-Add3DMesh modelSpace mSize nSize points))
    
    ;; 表示を変更
    (setq NewDirection (vlax-3d-point -1 -1 1))
    (setq activeViewport (vla-get-ActiveViewport doc))
    (vla-put-Direction activeViewport NewDirection)
    (vla-put-ActiveViewport doc activeViewport)
    (vla-ZoomAll acadObj)
    
    ;; N方向を閉じる
    (alert (strcat "polymesh の N方向は " (if (= (vla-get-NClose meshObj) :vlax-true) "閉じてます。" "開いてます。") ))
    (vla-put-NClose meshObj :vlax-true)
    (vla-Regen doc acActiveViewport)
    (alert (strcat "polymesh の N方向は " (if (= (vla-get-NClose meshObj) :vlax-true) "閉じてます。" "開いてます。") ))
)